Analysis of the Alternating Cube group with GAP

Topics that don't fit into any of the other forums.
Post Reply
Author Message
Brandon Enright
 Post subject: Analysis of the Alternating Cube group with GAP
Post Posted: Sat Jul 02, 2016 7:29 pm 
User avatar

Joined: Thu Dec 31, 2009 8:54 pm
Website: http://www.brandonenright.net
Location: Bay Area, California
A few years ago Oskar and Bram came up with the Alternating Cube:
Alternating Cube - view 1.jpg
This puzzle is a 2x2x2 where every clockwise move must be followed by a counter-clockwise move. Already a decent amount of analysis has been done on this puzzle so my goal here is to show all the analysis in a logical order with GAP and use GAP to answer some questions we have about the properties and restrictions this puzzle has.

If you want to skip the GAP analysis below here is a simple description of the Alternating Cube:

  • Like the 2x2x2, the Alternating Cube has 8 corners that can be twisted 3 ways and the twist of the last corner is determined by the twist of the other 7 corners, so, there is no difference in the behavior of corner orientation between the 2x2x2 and Alternating Cube
  • Like the 2x2x2 the Alternating Cube permutes 8 corners
  • Unlike the 2x2x2 where all 8 corners can be in any permutation (8! permutations), once 3 corners are placed on the Alternating Cube the remaining 5 can not be permuted at all (8! / 5! = 8 * 7 * 6 = 336 permutations)
  • Because the Alternating Cube corner permutations is a factor of 5! = 120 smaller than the 2x2x2, the total size of the Alternating Cube group is exactly 120 times smaller than the 2x2x2 group



Now on to my analysis. Here is my GAP file to make the groups:

Code: Select all

#                     +--------------+
#                     |    Up (Red)  |
#                     |  1         2 |
#                     |              |
#                     |              |
#                     |              |
#                     |  3         4 |
#                     |              |
#      +--------------+--------------+--------------+--------------+
#      | LEFT (Yellow)| FRONT (Blue) | RIGHT (Green)| BACK (White) |
#      |  5        06 |  7        08 |  9        10 | 11        12 |
#      |              |              |              |              |
#      |              |              |              |              |
#      |              |              |              |              |
#      | 13        14 | 15        16 | 17        18 | 19        20 |
#      |              |              |              |              |
#      +--------------+--------------+--------------+--------------+
#                     | Down (Orange)|
#                     | 21        22 |
#                     |              |
#                     |              |
#                     |              |
#                     | 23        24 |
#                     |              |
#                     +--------------+

R := ( 9,10,18,17)( 2,19,22, 8)( 4,11,24,16);
B := (11,12,20,19)( 2, 5,23,18)( 1,13,24,10);
D := (21,22,24,23)(13,15,17,19)(14,16,18,20);

# Use the mirror per Bram's trick to force alternation
M := (3,2)(7,10)(8,9)(15,18)(16,17)(21,24)(6,11)(5,12)(14,19)(13,20);

# If we want to make the full 2x2x2 group with all orientations
U := (1,2,4,3)(5,11,9,7)(12,10,8,6);
F := (7,8,16,15)(3,9,22,14)(6,4,17,21);

# This can only reach even permutations
# alternate := Group(R*B^-1, R*D^-1, B*R^-1, B*D^-1,D*R^-1, D*B^-1);

# Bram (http://twistypuzzles.com/forum/viewtopic.php?p=303916#p303916)
#
# There's a much more elegant encoding in GAP than encoding all
# possible two-move sequences. You use three moves: Rotating either R,
# U, or F, followed by mirror imaging the whole cube on the plane
# going through the RFU, RFD, LBU, and LBD vertices.

# This reaches all 24 orientations
altcube_mir := Group(R*M, B*M, D*M);

# This holds one sticker on one cube still to eliminate the extra
# orientations
altcube := Stabilizer(altcube_mir, 1, OnPoints);

# And a normal 2x2x2 to compare against
cube_222_all := Group(U, D, B, F, R);

# And hold one corner still to eliminate extra orientations
cube_222 := Stabilizer(cube_222_all, [1, 5, 12], OnTuples);
Here is the size of the Alternating Cube compared to a 2x2x2:

Code: Select all

gap> Size(altcube);
30618

gap> Size(cube_222);
3674160

gap> Size(cube_222) / Size(altcube);
120
We know the corners have three stickers that are attached to each other so the first thing to do is to get a list of the corner sticker blocks so we can examine corner orientations and permutations:

Code: Select all

gap> altcube_corner_blocks := Blocks(altcube_mir, MovedPoints(altcube_mir));
[ [ 1, 5, 12 ], [ 2, 10, 11 ], [ 3, 6, 7 ], [ 4, 8, 9 ], [ 13, 20, 23 ], [ 14, 15, 21 ], [ 16, 17, 22 ], 
  [ 18, 19, 24 ] ]

gap> cube_222_corner_blocks := Blocks(cube_222_all, MovedPoints(cube_222_all));
[ [ 1, 5, 12 ], [ 2, 10, 11 ], [ 3, 6, 7 ], [ 4, 8, 9 ], [ 13, 20, 23 ], [ 14, 15, 21 ], [ 16, 17, 22 ], 
  [ 18, 19, 24 ] ]
With the corner blocks, we can hold each block still with a stabilizer but let the stickers within the blocks twist. This will tell us how many different orientations are available for each position:

Code: Select all

gap> altcube_corner_twist := Stabilizer(altcube, altcube_corner_blocks, OnTuplesSets);
<permutation group of size 729 with 14 generators>

gap> cube_222_corner_twist := Stabilizer(cube_222, cube_222_corner_blocks, OnTuplesSets);
<permutation group of size 729 with 7 generators>
The size of these groups is the same even though GAP found different generators for them. We can identify this group and show they're the same group:

Code: Select all

gap> IdSmallGroup(altcube_corner_twist);
[ 729, 504 ]

gap> IdSmallGroup(cube_222_corner_twist);
[ 729, 504 ]

gap> SmallGroupsInformation(729);

  There are 504 groups of order 729.
  They are sorted by their ranks. 
     1 is cyclic. 
     2 - 101 have rank 2.
     102 - 414 have rank 3.
     415 - 496 have rank 4.
     497 - 503 have rank 5.
     504 is elementary abelian. 
[...]

gap> Factors(729);
[ 3, 3, 3, 3, 3, 3 ]
In other words, the corner twist groups are identical. They're just the group where there are 8 corners, one of them is held in place (so that we don't overcount), six are free to twist in any way they want, and the 8th can't twist freely because it's orientation is determined by the other 7.

This means the Alternating Cube doesn't have any surprises where corner twist is concerned. Let's look at the corners as a whole and examine how they permute. This can be done with a group action homomorphism where the three stickers on each corner are considered one unit:

Code: Select all

gap> altcube_corner_perm := Image(ActionHomomorphism(altcube_mir, altcube_corner_blocks, OnSets));
Group([ (1,5,6,8,3,2), (2,6,8,7,4,3), (2,3)(5,8)(6,7) ])

gap> cube_222_corner_perm := Image(ActionHomomorphism(cube_222_all, cube_222_corner_blocks, OnSets));
Group([ (1,2,4,3), (1,5,8,2), (3,4,7,6), (2,8,7,4), (5,6,7,8) ])
Now we have two groups that represent the permutation of the corners. Here are their sizes:

Code: Select all

gap> Size(altcube_corner_perm);
336

gap> Size(cube_222_corner_perm);
40320

gap> Size(cube_222_corner_perm) / Size(altcube_corner_perm);
120
There isn't any mystery with the 2x2x2 corner permutations. We know it's just the symmetric group of size 8 because it operates on 8 elements and 8! is 40320 and the transitivity of the group is 8 meaning there is an element of the group that can take any permutation of 8 elements to any other permutation of 8 elements:

Code: Select all

gap> Transitivity(cube_222_corner_perm);
8
But the Alternating Cube corner permutation group is different! It's 5! smaller which is a big hint that 5 of the 8 corners can't be permuted relative to each other at all. If this were true, we should be able to take any 3 corners and put them in any 3 spots and the group would be 3-transitive:

Code: Select all

gap> Transitivity(altcube_corner_perm);
3
This is a group where you can place any 3 pieces but that automatically places the other 5 pieces! There should be 8 ways to place the first piece, 7 ways for the second, and 6 ways for the third. 8 * 7 * 6 = 336 and this is the same size as the group:

Code: Select all

gap> Size(altcube_corner_perm) / (8 * 7 * 6);
1
This means there is only 1 group element for each possible positioning of 3 pieces so the group is sharply 3-transitive. We can have GAP identify the group for us:

Code: Select all

gap> IdSmallGroup(altcube_corner_perm);
[ 336, 208 ]

gap> SmallGroupsInformation(336);

  There are 228 groups of order 336.
  They are sorted by their Frattini factors. 
     1 has Frattini factor [ 42, 1 ].
     2 has Frattini factor [ 42, 2 ].
[...]
     6 has Frattini factor [ 42, 6 ].
     7 - 22 have Frattini factor [ 84, 7 ].
     23 - 47 have Frattini factor [ 84, 8 ].
     48 - 55 have Frattini factor [ 84, 9 ].
     56 has Frattini factor [ 84, 10 ].
     57 has Frattini factor [ 84, 11 ].
     58 - 73 have Frattini factor [ 84, 12 ].
     74 - 89 have Frattini factor [ 84, 13 ].
     90 - 105 have Frattini factor [ 84, 14 ].
     106 - 113 have Frattini factor [ 84, 15 ].
     114 has Frattini factor [ 168, 42 ].
     115 - 117 have Frattini factor [ 168, 45 ].
[...]
     204 - 207 have Frattini factor [ 168, 57 ].
     208 - 228 have trivial Frattini subgroup.
Group #208 is the PGL(2,7) group. Although you wouldn't want to try to solve the corner permutations via premade cycles, we can still get a list of all the possible types of cycles:

Code: Select all

gap> ConjugacyClasses(altcube_corner_perm);
[ ()^G, (3,4,6)(5,8,7)^G, (3,5,6,7,4,8)^G, (3,7)(4,5)(6,8)^G, (2,3,6,5,4,8,7)^G, (1,2)(3,5)(4,7)(6,8)^G, 
  (1,2,3,4,5,6,8,7)^G, (1,2,3,5,7,6,4,8)^G, (1,2,3,6)(4,7,5,8)^G ]

gap> List(ConjugacyClasses(altcube_corner_perm), Size);
[ 1, 56, 56, 28, 48, 21, 42, 42, 42 ]

gap> List(ConjugacyClasses(altcube_corner_perm), i -> Order(Representative(i)));
[ 1, 3, 6, 2, 7, 2, 8, 8, 4 ]
This means about the best you could do with premade cycles is a 2x3-cycle, a 3-2 swap, or a 4-2 swap. A much better strategy is to just manually place three corners by intuition because this will automatically place the other 5 for you. This should be pretty easy with practice.

Note, the corner permutation group we made didn't hold one corner fixed in space. If we do that it will tell us how many essentially different permutations are possible:

Code: Select all

gap> altcube_corner_perm_fixed := Stabilizer(altcube_corner_perm, 1, OnPoints);
Group([ (2,3)(5,8)(6,7), (2,6,8,7,4,3), (2,6,3,8,5,4) ])

gap> Size(altcube_corner_perm_fixed);
42
If we multiply the distinct permutations by the distinct orientations we should get the size of the whole group. This will tell us that there is no orientation restriction based on the permutation of the corners:

Code: Select all

gap> Size(altcube_corner_perm_fixed) * Size(altcube_corner_twist);
30618
Here is some information about the group of distinct permutations:

Code: Select all

gap> IdGroup(altcube_corner_perm_fixed);
[ 42, 1 ]

gap> SmallGroupsInformation(42);

  There are 6 groups of order 42.
    1 is of type 7:6.
    2 is of type 7:3x2.
    3 is of type S3x7.
    4 is of type D14x3.
    5 - 5 are of types 3:2+7:2.
    6 is of type c42.
This group is 2-transitive. You can just call one of the corners solved and place the other two corners correctly and the remaining 6 will fall into place.

Code: Select all

gap> Transitivity(altcube_corner_perm_fixed);
2
Finally, because Oskar asked and because Matt answered but wasn't sure, a half turn is not possible:

Code: Select all

gap> (U*U) in altcube_mir;
false
The hard part of solving the Alternating Cube will be to find a useful routine to twist corners. Once found though, the Alternating Cube should be pretty easy to solve.

_________________
Twisty Renderer -- Jaap's Spheres with POV-Ray
Top
  Profile  
Reply with quote  
wwwmwww
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Sat Jul 02, 2016 8:13 pm 
User avatar

Joined: Thu Dec 02, 2004 12:09 pm
Website: http://www.wwwmwww.com/
Location: Queen Creek, AZ
Nice!!! I'm really enjoying these Brandon. Keep it up.

Carl

_________________
-
Image

Image
Top
  Profile  
Reply with quote  
Brandon Enright
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Sat Jul 02, 2016 9:06 pm 
User avatar

Joined: Thu Dec 31, 2009 8:54 pm
Website: http://www.brandonenright.net
Location: Bay Area, California
If you solve the corner permutation first and then you want to solve the orientations, this is the best you can do:

Code: Select all

States at depth 0 : 1
States at depth 1 : 0
States at depth 2 : 0
States at depth 3 : 0
States at depth 4 : 0
States at depth 5 : 0
States at depth 6 : 6
States at depth 7 : 0
States at depth 8 : 6
States at depth 9 : 0
States at depth 10 : 62
States at depth 11 : 0
States at depth 12 : 236
States at depth 13 : 0
States at depth 14 : 214
States at depth 15 : 0
States at depth 16 : 204
States at depth 17 : 0
States at depth 18 : 0
So worst case it takes you 16 moves to fix all corner orientations. The states at depth 6 are all the variations on [A B']x3 which twist 6 corners. The states at depth 8 are all the variations on [A':[B C']x3] that twist 6 corners. All states with only two corners twisted require 16 moves (even for non-adjacent corners). Almost all states that have 3 corners twisted need 12 moves but a few need 14 moves.

_________________
Twisty Renderer -- Jaap's Spheres with POV-Ray
Top
  Profile  
Reply with quote  
Bram
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Sun Jul 03, 2016 7:42 am 

Joined: Sat Mar 22, 2003 9:11 am
Website: http://bitconjurer.org/
Location: Marin, CA
Brandon Enright wrote:So worst case it takes you 16 moves to fix all corner orientations. All states with only two corners twisted require 16 moves (even for non-adjacent corners). Almost all states that have 3 corners twisted need 12 moves but a few need 14 moves.
Sounds like the most practical human solving approach would be to use a sequence which rotates three adjacent corners clockwise. Care to share a sequence for that?
Top
  Profile  
Reply with quote  
Bram
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Sun Jul 03, 2016 7:48 am 

Joined: Sat Mar 22, 2003 9:11 am
Website: http://bitconjurer.org/
Location: Marin, CA
Brandon Enright wrote:Group #208 is the PGL(2,7) group.
Well that's interesting. Apparently PGL(2,7) is exactly this group - the 7 elements other than the one fixed corner. Viewing it as the alternating 2x2x2 seems to be a novel and potentially useful insight. Presumably the alternating 2x2x2x2 corresponds to PGL(2,15).
Top
  Profile  
Reply with quote  
Bram
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Sun Jul 03, 2016 2:35 pm 

Joined: Sat Mar 22, 2003 9:11 am
Website: http://bitconjurer.org/
Location: Marin, CA
The next question is the alternating skewb. I suspect that that one is fairly normal. It appears that weird groups only appear in special circumstances and don't usually apply to other pieces within the same group or generalizations of the puzzle. The alternating Maltese Cube is probably fairly normal as well. Has GAP of Anisotropic Evil Twin been done? I seem to remember that one being 'discovered' from such an analysis, but I don't know if it was broken down into appropriate subgroups.
Top
  Profile  
Reply with quote  
Brandon Enright
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Sun Jul 03, 2016 3:20 pm 
User avatar

Joined: Thu Dec 31, 2009 8:54 pm
Website: http://www.brandonenright.net
Location: Bay Area, California
Bram wrote:
Brandon Enright wrote:So worst case it takes you 16 moves to fix all corner orientations. All states with only two corners twisted require 16 moves (even for non-adjacent corners). Almost all states that have 3 corners twisted need 12 moves but a few need 14 moves.
Sounds like the most practical human solving approach would be to use a sequence which rotates three adjacent corners clockwise. Care to share a sequence for that?
Sure, this twists two adjacent corners:

Code: Select all

State: AEGLBHIJKFDCMPQSTVWNRUOX3 -> [D', B, D', R, B', R, B', D, R', B, R', D, B', R, D', R]
And this twists three corners on a face:

Code: Select all

State: CEGKAHILJFDBMPQSTVWNRUOX3 -> [D', B, R', B, D', B, D', R, D', R, B', R]
The state string is mostly impenetrable for a human but it makes the cycles a lot easier in code.

_________________
Twisty Renderer -- Jaap's Spheres with POV-Ray
Top
  Profile  
Reply with quote  
Bram
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Sun Jul 03, 2016 5:14 pm 

Joined: Sat Mar 22, 2003 9:11 am
Website: http://bitconjurer.org/
Location: Marin, CA
Answering my own question, analysis of anisotropic evil twin is here. No weird subgroups. The value 8 * 6 * 4 * 2 is just 4! * 2^4.

But the Alternating Skewb is much more interesting. Allagem did an almost complete analysis here. The orientations don't do anything unusual, but both the corner and face positions are unusual. The only thing left is the names of those groups. Anyone care to plug them into GAP and let us know?

So the pattern seems to be that alternating puzzles have uninteresting orientations but interesting positions. That leads to the questions: What about the piece positions of the Alternating Pentultimate and the Alternating Deep Cut Face Turning Icosahedron? I can't believe I just types that sequence of words without irony. There's lots more mathematical stuff to explore in 4d, but those are a bit hard to build.
Top
  Profile  
Reply with quote  
Bram
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Sun Jul 03, 2016 5:44 pm 

Joined: Sat Mar 22, 2003 9:11 am
Website: http://bitconjurer.org/
Location: Marin, CA
Brandon Enright wrote:this twists two adjacent corners:

Code: Select all

State: AEGLBHIJKFDCMPQSTVWNRUOX3 -> [D', B, D', R, B', R, B', D, R', B, R', D, B', R, D', R]
And this twists three corners on a face:

Code: Select all

State: CEGKAHILJFDBMPQSTVWNRUOX3 -> [D', B, R', B, D', B, D', R, D', R, B', R]
Thank you. Given that on a 2x2x2 both U and D do the same thing, there are a lot of equivalent ways of writing those sequences. Are any of them more intuitive to a human? In particular, is there any way of doing them which results in the edges being unchanged at the end?
Top
  Profile  
Reply with quote  
Brandon Enright
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Sun Jul 03, 2016 5:52 pm 
User avatar

Joined: Thu Dec 31, 2009 8:54 pm
Website: http://www.brandonenright.net
Location: Bay Area, California
Bram wrote:
Brandon Enright wrote:this twists two adjacent corners:

Code: Select all

State: AEGLBHIJKFDCMPQSTVWNRUOX3 -> [D', B, D', R, B', R, B', D, R', B, R', D, B', R, D', R]
And this twists three corners on a face:

Code: Select all

State: CEGKAHILJFDBMPQSTVWNRUOX3 -> [D', B, R', B, D', B, D', R, D', R, B', R]
Thank you. Given that on a 2x2x2 both U and D do the same thing, there are a lot of equivalent ways of writing those sequences. Are any of them more intuitive to a human?
Almost certainly. Unfortunately the way my code finds them I have no idea. I'd have to find all variations (I guess there must be 2^11 versions right?) and then see which follow patterns humans find useful.

Also, doesn't the alternating nature destroy all commutators? Is there any X Y X' Y' that doesn't violate the alternating restriction? My intuition says "no" but I haven't worked on it very hard.

Bram wrote:In particular, is there any way of doing them which results in the edges being unchanged at the end?
I guess you mean edges of a 3x3x3? If so, the answer is no. The shortest routine to twist three adjacent corners without affecting edges is 13 face moves so this can never be clean on a Rubik's Cube.

_________________
Twisty Renderer -- Jaap's Spheres with POV-Ray
Top
  Profile  
Reply with quote  
Bram
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Sun Jul 03, 2016 6:22 pm 

Joined: Sat Mar 22, 2003 9:11 am
Website: http://bitconjurer.org/
Location: Marin, CA
Brandon Enright wrote:I'd have to find all variations (I guess there must be 2^11 versions right?) and then see which follow patterns humans find useful.
It might be 2^12.
Brandon Enright wrote:Also, doesn't the alternating nature destroy all commutators? Is there any X Y X' Y' that doesn't violate the alternating restriction? My intuition says "no" but I haven't worked on it very hard.
That's a good point. I think it does. That might be why we're seeing so many interesting groups show up. Current score: alternating puzzles have 3 unusual groups in 2 puzzles. Regular doctrinaire twisty puzzles have one unusual group in hundreds of puzzles. That raises the next question: Why do commutators fail in the Trapentrix? Also maybe the gear positions in the alternating maltese cube are worth a look.
Top
  Profile  
Reply with quote  
Brandon Enright
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Sun Jul 03, 2016 8:17 pm 
User avatar

Joined: Thu Dec 31, 2009 8:54 pm
Website: http://www.brandonenright.net
Location: Bay Area, California
Bram wrote: Why do commutators fail in the Trapentrix?
I don't think I'd classify commutators as useless for the Trapentrix. First off, for all the pieces that aren't the points commutators are directly useful. Secondly, you can still use commutators for the points but your commutators won't form nice 3-cycles.

To get a 3-cycle out of a commutator you need the two halves of the commutator to overlap by only 1 piece. I think I'm simplifying a bit here but the problem with the Trapentrix is that one move turns 6 pieces and there are only 9 pieces total so there just isn't enough room to stuff pieces in other locations so that all you have is 1 piece of overlap over the full A B A' B' sequence of moves.

I've found commutators to do other cycles like a 9 cycle and a 3x3-cycle.

I think if we're going to find other weird groups we're most likely going to find them when there are a small number of pieces and a large portion of them get moved with every turn. This makes for highly constrained spaces that limit freedom. With limited freedom comes strange interactions.

_________________
Twisty Renderer -- Jaap's Spheres with POV-Ray
Top
  Profile  
Reply with quote  
bobthegiraffemonkey
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Mon Jul 04, 2016 9:07 am 
User avatar

Joined: Fri Jan 29, 2010 2:34 pm
Location: Scotland, UK
Brandon Enright wrote:Also, doesn't the alternating nature destroy all commutators? Is there any X Y X' Y' that doesn't violate the alternating restriction? My intuition says "no" but I haven't worked on it very hard.
It seems that commutators work, but only if both X and Y have even length, and I'm not sure exactly what implications that has. This should help show why:
[1,1]: a b' a' b
[1,2]: a b'c a' c'b
[2,2]: ab' cd' ba' dc'
Top
  Profile  
Reply with quote  
Bram
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Mon Jul 04, 2016 10:53 am 

Joined: Sat Mar 22, 2003 9:11 am
Website: http://bitconjurer.org/
Location: Marin, CA
bobthegiraffemonkey wrote: It seems that commutators work, but only if both X and Y have even length, and I'm not sure exactly what implications that has. This should help show why:
[1,1]: a b' a' b
[1,2]: a b'c a' c'b
[2,2]: ab' cd' ba' dc'
Not sure what you mean. If A has even length and B has odd length then you can do ABA'B', which is a fair point, but the ones you list seem to violate the alternating rule.
Top
  Profile  
Reply with quote  
jaap
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Mon Jul 04, 2016 2:48 pm 
User avatar

Joined: Wed Mar 15, 2000 9:11 pm
Website: http://www.jaapsch.net/puzzles/
Location: Delft, the Netherlands
Bram wrote:
bobthegiraffemonkey wrote: It seems that commutators work, but only if both X and Y have even length, and I'm not sure exactly what implications that has. This should help show why:
[1,1]: a b' a' b
[1,2]: a b'c a' c'b
[2,2]: ab' cd' ba' dc'
Not sure what you mean. If A has even length and B has odd length then you can do ABA'B', which is a fair point, but the ones you list seem to violate the alternating rule.
I'm not sure what you mean. What Bob said seems perfectly clear to me. The [2,2] commutator works, it follows the alternating rule, and by the same token so does any other commutator of X and Y where X and Y are both of even length. If either of X or Y have odd length, their commutator will violate the rule.

_________________
Jaap

Jaap's Puzzle Page: https://www.jaapsch.net/puzzles/
Other stuff: https://www.jaapsch.net/
Top
  Profile  
Reply with quote  
Bram
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Mon Jul 04, 2016 3:53 pm 

Joined: Sat Mar 22, 2003 9:11 am
Website: http://bitconjurer.org/
Location: Marin, CA
jaap wrote:
Bram wrote:
bobthegiraffemonkey wrote: It seems that commutators work, but only if both X and Y have even length, and I'm not sure exactly what implications that has. This should help show why:
[1,1]: a b' a' b
[1,2]: a b'c a' c'b
[2,2]: ab' cd' ba' dc'
The [2,2] commutator works, it follows the alternating rule, and by the same token so does any other commutator of X and Y where X and Y are both of even length. If either of X or Y have odd length, their commutator will violate the rule.
Don't even length sequences leave the handedness the same as they started, so no commutator with all even length sequences will ever contain an inverse? It looks like [2,2] works if they all have odd lengths though. Also [1,1] works if a + b is odd, and [1,2] works if a is odd and b and c are even.
Top
  Profile  
Reply with quote  
bobthegiraffemonkey
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Mon Jul 04, 2016 4:24 pm 
User avatar

Joined: Fri Jan 29, 2010 2:34 pm
Location: Scotland, UK
It seems I should have explained my notation a little better, though jaap has the right idea I think. All of a,b,c,d are single twists, and the numbers in square brackets indicate the number of twists in that part of the commutator. Thus, [1,1] is a commutator where both X and Y are a single twist, and I put e.g. b' before b to help indicate the attempt to have alternating twists. That is, if the move a is clockwise, then the move b' is counter-clockwise, and so on for all letters. Then:

[1,1]: [a,b']=a b' a' b (doesn't work since X and Y have odd length)
[1,2]: [a,b'c] = a b'c a' c'b (doesn't work since X has odd length, by symmetry [2,1] also doesn't work)
[2,2]: [ab',cd'] = ab' cd' ba' dc' (this works since both X and Y have even length, in this case 2 twists)

Does that help? Sorry for any confusion, I typed my last post quickly.
Top
  Profile  
Reply with quote  
Bram
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Mon Jul 04, 2016 5:50 pm 

Joined: Sat Mar 22, 2003 9:11 am
Website: http://bitconjurer.org/
Location: Marin, CA
Oh I see now. I forgot that when you do combinators you reverse the sequence, not just the handedness. Not thinking so straight today.
Top
  Profile  
Reply with quote  
wwwmwww
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Tue Jul 05, 2016 11:47 am 
User avatar

Joined: Thu Dec 02, 2004 12:09 pm
Website: http://www.wwwmwww.com/
Location: Queen Creek, AZ
Bram wrote:Presumably the alternating 2x2x2x2 corresponds to PGL(2,15).
Does the "alternating" idea even translate to 4D? On a 3D twisty puzzle a given layer can just go clockwise or counter-clockwise about a single axis. In 4D, there are many different ways a given cell can rotate. I'm not even certain of the appropriate terminology to use. But if one looks at the 3D stickers they are free to rotate about the axes through the face centers, the axes though opposite edges, and the body diagonals. That is 3+6+4 or 13 possible axis of rotation for each cell. So lets say you have an alternating 2x2x2x2 and need to make a clockwise turn, are all 13 of these possibilities available to you for each cell?

https://www.youtube.com/watch?v=yhPH1369OWc&t=6m19s

It appears a single body diagonal turn can be replaced with 2 face center turns and a rotation about an axis between 2 edges can be replaced with 3 face center turns... but then another problem seems apparent to me. Even if we limit ourselves to face center turns, how does one distinguish clockwise from counter-clockwise as a clockwise turn looks like a counter-clockwise turn when viewed from the opposite side of the cell?

Carl

_________________
-
Image

Image
Top
  Profile  
Reply with quote  
wwwmwww
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Tue Jul 05, 2016 1:53 pm 
User avatar

Joined: Thu Dec 02, 2004 12:09 pm
Website: http://www.wwwmwww.com/
Location: Queen Creek, AZ
All,

I suggested this thread be listed in the links section here:
http://twistypuzzles.com/cgi-bin/puzzle.cgi?pkey=4229

I know threads slowly die and get buried eventually but this analysis by Brandon may prove interesting to others that come along much latter so I think the museum is a good place to collect them as links. I'll try to make more link suggestions in the future but ANYONE can make these types of suggestions just by clicking on the yellow plus next to the word LINKS.

Brandon, I'd suggest you add links for your detailed GAP analyses to their respective puzzles.

And fellow designers, when you introduce a new puzzle in the new puzzle section I'd suggest you add that thread as a link to the eventual entry that puzzle will get in the museum. I'm often looking at a museum entry and wondering what was said about the puzzle when it was first introduced. I haven't been doing this myself yet but I will try to going forward and when I have time work on the backlog as well.

Carl

_________________
-
Image

Image
Top
  Profile  
Reply with quote  
Bram
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Thu Jul 07, 2016 6:31 pm 

Joined: Sat Mar 22, 2003 9:11 am
Website: http://bitconjurer.org/
Location: Marin, CA
wwwmwww wrote:
Bram wrote:Presumably the alternating 2x2x2x2 corresponds to PGL(2,15).
Does the "alternating" idea even translate to 4D?
Yes it does. The 'simplest to build' 4d example only has four linear rotations, there which are on a 2x2x2, and one more in the extra direction.
Top
  Profile  
Reply with quote  
wwwmwww
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Fri Jul 08, 2016 2:24 pm 
User avatar

Joined: Thu Dec 02, 2004 12:09 pm
Website: http://www.wwwmwww.com/
Location: Queen Creek, AZ
Bram wrote:Yes it does. The 'simplest to build' 4d example only has four linear rotations, there which are on a 2x2x2, and one more in the extra direction.
Does it look like this?
2x2x2x2.PNG
2x2x2x2.PNG (76.9 KiB) Viewed 354 times
If so can you show me a clockwise rotation of the red cell? Is there enough information here to be able to tell which axis it rotates about? If not, what else do you need?

And is this "simplest-to-build 2x2x2x2" before the alternating restriction is placed on it the full 2x2x2x2 or a subset of the 2x2x2x2 itself?

Some 4 dimensional being is probably looking through me at the moment thinking "Come on Carl, this is as easy as righty tighty lefty loosey." Maybe the light will come on and the door will open eventually but right now I feel about like this.

Image

Carl

_________________
-
Image

Image
Top
  Profile  
Reply with quote  
Brandon Enright
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Fri Jul 08, 2016 3:36 pm 
User avatar

Joined: Thu Dec 31, 2009 8:54 pm
Website: http://www.brandonenright.net
Location: Bay Area, California
4D rotations are not intuitive at all. They don't quite follow the rules you'd expect them to. https://en.wikipedia.org/wiki/Rotations ... dean_space explains it a bit but it's hard to understand. http://eusebeia.dyndns.org/4d/vis/10-rot-1 explains it in a much more easily understood manner.

I think we should first ask what the 2x2x2 is before we jump to extending it to the 2x2x2x2.

One answer is the puzzle is 3D (a cube) but the faces are 2D (squares). We think of these faces rotating about an axis in 3D but I think it's more appropriate to think of the squares as rotating around a point at their center.

If we extend this to 4D the whole puzzle is 4D (a tesseract) and the faces are 3D (cubes). Rotations of the faces are about a point at the center of a cube. A square only had 4 positions but a cube has 24.

This is the approach that MC4D and Gelatinbrain have both used.

I think the approach Bram is talking about is to extend a 2x2x2 into 4D where you still do 2D rotations about an axis embedded in 4D. I don't know what that puzzle looks like but it's not the same puzzle as MC4D.

_________________
Twisty Renderer -- Jaap's Spheres with POV-Ray
Top
  Profile  
Reply with quote  
Bram
 Post subject: Re: Analysis of the Alternating Cube group with GAP
Post Posted: Sun Jul 10, 2016 6:46 pm 

Joined: Sat Mar 22, 2003 9:11 am
Website: http://bitconjurer.org/
Location: Marin, CA
By the 2x2x2x2 I'm imagining a puzzle with 16 pieces and 4 possible slices. Each of the pieces is a hypercube one of whole vertices is at the center and that vertex must always stay at the center.
Top
  Profile  
Reply with quote  
Post Reply

Return to “General Puzzle Topics”